[엑셀] 매크로로 선택영역의 특정 문자만 색 변환하기

주소: http://unikys.tistory.com/307

* 목표: 엑셀에서 선택한 영역을 가져와서 각 문자열의 문자 중에 입력한 단어가 있으면 색을 변환하는 매크로 작성

 

* 작성 환경: 엑셀 2010

 

: 예를 들면 아래와 같은 엑셀이 있을 경우 'fer'를 빨간색으로 변환하고 싶다.

 

 

 

 

1. 매크로 생성

: 위의 메뉴바에서 보기 > 매크로 > 매크로 보기를 선택

: 매크로 이름에 'WordColor' 등 매크로 이름을 넣으면 오른쪽에 '만들기' 버튼이 활성화 된다.

: '만들기' 버튼 클릭

 

 

 

: 그러면 아래와 같이 비쥬얼 베이직 모듈 작성 윈도우가 열린다. 여기다가 매크로를 작성한다.

 

 

2. 매크로 작성

: 아래의 소스를 매크로에 작성한다.

Sub WordColor()
    Dim cell As Range, word As String, startIndex As Integer
    
    word = InputBox(Prompt:="단어를 입력하세요", Title:="문자열 색 변환")

    If Len(word) > 0 Then
        For Each cell In Selection
            startIndex = InStr(1, cell, word, vbTextCompare)
    
            If startIndex > 0 Then
                cell.Characters(startIndex, Len(word)).Font.Color = RGB(0, 0, 255)
                cell.Characters(startIndex, Len(word)).Font.Bold = True
            End If
        Next cell
    End If
End Sub

 

: 위의 소스 코드를 각 줄마다 설명해보면,

 

    Dim cell As Range, word As String, startIndex As Integer

 

: 변수 선언을 하는 부분이다. cell은 이후 사용자가 선택한 영역의 각 셀을 저장할 변수, word는 사용자가 입력할 색을 변환 시킬 문자열, startIndex는 각 셀에 문자열이 있는지 여부와 위치를 저장할 변수이다.

 

 

    word = InputBox(Prompt:="단어를 입력하세요", Title:="문자열 색 변환")

 

: InputBox는 사용자가 입력을 할 수 있는 다이얼로그를 띄우는 명령이다. 위의 명령을 실행하면 아래와 같은 다이얼로그가 띄워진다.

 

 

 

 

If Len(word) > 0 Then
    ' 중략
End If

: 사용자가 입력한 문자열 (word)의 길이가 0 이상이면 진행하고, 0이면 진행하지 않는다. 사용자가 그냥 확인을 눌렀거나 취소를 눌렀을 때 해당된다.

 

    For Each cell In Selection
        ' 중략
    Next cell

 

: Selection은 사용자가 선택한 영역 범위이고, 영역 범위 내의 각 셀을 선택하여 cell에 넣고 '중략 에 들어가는 동작들을 실행한다. 아래는 '중략에 해당하는 부분이다.

 

        startIndex = InStr(1, cell, word, vbTextCompare)

 

: InStr 함수를 이용해서 셀에 word가 있는지 구분한다. InStr은 만약 cell 안에 word가 있는지 1번째 알파벳부터 비교를 하고 그 시작 위치를 반환하여 startIndex에 저장한다.

 

        If startIndex > 0 Then
            ' 중략
        End If

 

: cell안에 word가 있으면 '중략의 부분을 실행한다. 아래의 부분이 '중략에 해당한다.

 

            cell.Characters(startIndex, Len(word)).Font.Color = RGB(0, 0, 255)
            cell.Characters(startIndex, Len(word)).Font.Bold = True

 

: 선택 영역 내부의 셀 (cell)의 문자들을 선택하는데, 위에서 startIndex로 얻어온 word의 시작 위치부터 word의 길이만큼 (Len(word)) 선택하여 Font를 수정한다. Font.Color = RGB(0,0,255)은 색을 파란색으로 설정하게 되고, 이 부분을 수정하면 색이 변환되는 색을 수정할 수 있다. Font.Bold = True로 설정하면 해당하는 범위의 문자들이 볼드체가 된다.

 

 

3. 매크로 실행

: 아래와 같이 작성되었으면 일단 엑셀 셀 중에서 문자열 색을 바꾸길 원하는 부분을 먼저 선택한다.

: 아래의 비쥬얼 베이직 화면에서는 윗쪽 중간의 '재생/실행' 버튼이나 "F5"를 눌러서 실행한다.

: 엑셀 쪽에서 실행하려면 보기 > 매크로 > 매크로 보기 > 매크로 선택한 다음에 실행 버튼을 누르면 된다.

 

 

 

: 그럼 위의 InputBox로 인하여 문자열을 입력받게 되고,

 

 

: 그러면 엑셀을 보면 선택한 영역에 위의 문자열들이 바뀐 것을 볼 수 있다.

 

 

 

* 주의

- 변환하기 전에 바꾸고자하는 범위를 먼저 선택해야한다.

- 바꾸고 나면 취소가 안되고, 글 서식을 다시 설정해야한다.

- 매크로를 저장하려면 xlsm 파일이나 xls (2003 이전 버전 파일)로 저장해야한다.

- 보안 설정을 해제해줘야한다. 파일 > 옵션 > 보안 센터 > 보안 센터 설정 > 매크로 설정으로 들어가서 '모든 매크로 포함'과 'VBA 프로젝트 개체 모델에 안전하게 액세스할 수 있음'을 체크한다.

- InStr로 한번만 체크하기 때문에 문자열을 검색했을 때 나온 가장 먼저 나온 부분의 색만 변환하게 된다. 예를 들면 're'의 색을 변환하고자 할 때 reference 가 있으면 첫번째 're'ference 의 색만 변환된다. 뒷쪽을 할지/앞쪽을 할지 아니면 모든 문자열을 바꿀지 여부를 자동화하려면 추가 작업이 필요하다.

- 변환되는 다른 색으로 바꾸고자 한다면 매크로 안에서 RGB(0,0,255) 이 부분의 RGB 값을 바꾸면 된다.

 

 

* 아래의 첨부 파일은 매크로가 포함되어있으며, 범위를 선택하고 'CTRL+m'의 단축키를 누르면 실행할 수 있게 되어있다.

  

 WordColor.xlsm